! File : apdlANSYS- deformación en placa de elemento shell181-DPP.txt
! Descripción: DEFORMACION DE UNA PLACA
! Autor : Darwin Patiño Pérez
! Mail : [email protected],[email protected],[email protected]
! Fecha : 17/03/2016
! Departamento: Ingeniería Computacional Industrial – UCA
/PREP7
smrt,off
ANTYPE,STATIC ! DEFINICION DEL TIPO DE ANALSIS
K,1,10,13 ! DEFINE KEYPOINTS
K,2,12,13
k,3,14,13
K,4,10,16
K,5,11,16
k,6,12,15
k,7,13,16
K,8,14,16
K,9,10,19
k,10,12,17
K,11,12,19
k,12,14,19
k,13,12,16
L,1,2 !L1
L,2,6 !L2
LARC,5,6,13,1 !L3 - ARCO LARC Pi,Pf,EJE,RADIO
L,1,4 !L4
L,4,5 !L5
L,2,3 !L6
L,3,8 !L7
LARC,6,7,13,1 !L8 - ARCO
L,7,8 !L9
L,4,9 !L10
L,9,11 !L11
LARC,5,10,13,1 !L12 - ARCO
L,10,11 !L13
LARC,7,10,13,1 !L14 - ARCO
L,8,12 !L15
L,11,12 !L16
AL,1,2,3,5,4 !A1 - AREA
AL,6,7,9,8,2 !A2 - AREA
AL,5,12,13,11,10 !A3 - AREA
AL,9,15,16,13,14 !A4 - AREA
ET,1,SHELL181, , ,2 ! DEFINIR UN TIPO DE ELEMENTO LOCAL DESDE LA LIBRERIA DE ELEMENTOS
MP,EX,1,4.32E8 ! MATERIAL PROPERTIES
MP,NUXY,1,0.0
MP,DENS,1,36.7347
SECTYPE,1,SHELL !la sección es una cascara
SECDATA,0.25,1,0,5 !espesor de la cascara
ESIZE,0.5 ! defino si en el mallado las aberturas son mas cerradas o no
AMESH,1,4 ! generates nodes and area elements within areas
NSEL,S,LOC,Y,13 ! SELECCIONAR SELECION,LOC,EJE DONDE ESTAN
NPLOT ! PARA VISUALIZAR LO SEECCIONADO
D,ALL,ALL ! eliminar a todos los nodos seleccionados le quito todos los grados de libertad
NSEL,S,LOC,Y,19
NPLOT
F,ALL,FY,1 ! FUERZAS APLICADAS FY fuerza en Y de 1
NSEL,ALL ! SELECCIONAR TODOS
NPLOT ! PARA VERLOS
FINISH
/SOLU
ALLSEL
SOLVE
FINISH